#!perl
use Cassandane::Tiny;

# mailboxidexists finds another user's mailbox only if we can see it
sub test_mailboxidexists_otheruser_acl
    :NoAltNameSpace
{
    my ($self) = @_;

    my $admintalk = $self->{adminstore}->get_client();
    my $talk = $self->{store}->get_client();

    $self->{instance}->create_user('alice');
    $admintalk->create("user.alice.target") || die;
    $admintalk->setacl("user.alice.target", 'anyone' => 'p') || die;

    my $entry = '/shared/vendor/cmu/cyrus-imapd/uniqueid';
    my $res = $admintalk->getmetadata("user.alice.target", $entry);
    my $id = $res->{"user.alice.target"}{$entry};
    $self->assert_not_null($id);

    $talk->create("INBOX.found") || die;
    $talk->create("INBOX.notfound") || die;

    $self->{instance}->install_sieve_script(<<EOF2
require ["fileinto", "mailboxid"];
if mailboxidexists "$id" { fileinto "INBOX.found"; }
else { fileinto "INBOX.notfound"; }
EOF2
    , username => 'cassandane');

    xlog $self, "without lookup rights, the mailbox isn't found";
    my $msg1 = $self->{gen}->generate(subject => "Message 1");
    $self->{instance}->deliver($msg1, users => [ 'cassandane' ]);
    $self->{store}->set_folder('INBOX.notfound');
    $self->check_messages({ 1 => $msg1 }, check_guid => 0);

    xlog $self, "with lookup rights, it is";
    $admintalk->setacl("user.alice.target", 'cassandane' => 'l') || die;
    my $msg2 = $self->{gen}->generate(subject => "Message 2");
    $msg2->set_attribute(uid => 1);
    $self->{instance}->deliver($msg2, users => [ 'cassandane' ]);
    $self->{store}->set_folder('INBOX.found');
    $self->check_messages({ 1 => $msg2 }, check_guid => 0);
}
